Распарсить две группы файлов и склеить в один

Но, видимо, что-то пошло не так. Что именно, ткните?

Вот: «решаю через sed».

cat f1
param1=1x1
param2=1x2
param3=1x3
param4=1x4

cat f2
param1=2x1
param2=2x2
param3=2x3
param4=2x4

for i in f*; do cat "$i" | grep param[3,4] | awk -F"=" '{print $2}' | awk 'BEGIN {FS="\n"; RS=""} {print $1,":",$2}' >> final; done

cat final 
1x3 : 1x4
2x3 : 2x4

Может быть немного сложно вышло, но по другому не надумал...

А чтобы убрать побелы вокруг ":" надо добавить OFS=«»

{FS="\n"; RS=""; OFS=""}

Или вообще проще

for i in f*; do cat "$i" | grep param[3,4] | awk -F"=" '{print $2}' | awk 'BEGIN {FS="\n"; RS=""; OFS=":"} {print $1,$2}' >> final; done

cat можно убрать. зачем он?

for i in f*; do grep param[3,4] "$i" | awk -F"=" '{print $2}' | awk 'BEGIN {FS="\n"; RS=""; OFS=":"} {print $1,$2}' >> final; done

Ага, осталось от проверки файлов по отдельности. Конечно нужно убрать.

for i in f*; do cat "$i"

можно проще:

cat f*

Не уверен, но вроде без итерации выдаст только один результат

можно проще:

... когда файлов мало, а когда много — уже нельзя, в отличие от
for i in f*; do ...; done

А поскольку доподлинно неизвестно, мало или много, то нельзя, но если очень хочется...

Ничего подобного.

Это же задача для awk!

BEGIN {
  FS="="
  OFS=":"
}

FNR==1&&NF!=1 { #в начале каждого файла, кроме первого
  print param3, param4 # выдаём результат
}

FNR==1 { #в начале каждого файла сбрасываем
  param3=""
  param4=""
}

$1=="param3" { param3=$2; }
$1=="param4" { param4=$2; }

END {
  print param3, param4
}

Запускать так:

awk -f parse.awk все твои файлы

Ничего подобного

Вы хотели сказать, что при
cat f* ...
не сработает глобинг и команда cat в свои параметры получит именно один параметр «f*» вместо пачки имен, попавших под указанную маску, а превышение предельного размера (то самое «много файлов») НЕ будет сопровождаться ошибкой «Argument list too long»?

Если да, то нет :-)

С учётом https://www.gnu.org/software/gawk/manual/html_node/BEGINFILE_002fENDFILE.html можно упростить:

BEGIN {
  FS="="
  OFS=":"
}

BEGINFILE { #в начале каждого файла сбрасываем
  param3=""
  param4=""
}

$1=="param3" { param3=$2; } # эти части придётся переписать, если значения полей содержат "=". Это несложно - удаляем $1 и используем $0 вместо $2
$1=="param4" { param4=$2; } 

ENDFILE {
  print param3, param4
}

Почему вы думаете, что на for это ограничение не распространяется?

Почему вы думаете, что на for это ограничение не распространяется?

В zsh распространяется, ему нужно setopt nullglob или саму маску квалифицировать *(N). Но кто ж в здравом уме для zsh скриптует?

В bash не распространяется.
Про остальные *sh — оставим в качестве домашнего задания...

Я не про пустой glob, а про «Argument list too long».

Я не про пустой glob, а про «Argument list too long».

Я тоже. Можете проделать в bash эксперимент:
1) создать в каталоге множество файлов с длинными именами,
2) получить по ls * заветное «Argument list too long»,
3) проверить for f in *; do echo $f; done,
4) погрузить zsh и попытаться выполнить (4), получить «Argument list too long».

Проверил, да, действительно, bash в for и во встроенные команды передаёт любое количество аргументов, лишь бы памяти хватило. xargs мне по-прежнему милей.