Задать значение переменной или define на этапе компиляции в CMake

set( VERSION_BUILD )
exec_program( "cat" ARGS "build-number.txt"
              OUTPUT_VARIABLE VERSION_BUILD )
message("Version build: " ${VERSION_BUILD} )

Добавил ..

а, тебе при каждой сборке нужно инкремент. Тогда не то.

И еще добавил.

Все оказывается просто. смотри тут

https://github.com/erichschroeter/cmake-auto-increment-build-number

..
set(VERSION_OUTPUT ${PROJECT_BINARY_DIR}/src/version.h)
..
-i
	> ${VERSION_OUTPUT}

это создается файл. Про такой способ знаю. Интересует конструкция CMake, которая генерирует аналог для Makefile:

VERSION_BUILD=$(shell cat build-number.txt)

создать define на этапе компиляции?

add_definitions(-DMYDEFINE)

https://cmake.org/cmake/help/v3.0/command/add_definitions.html

нужно не просто -DMYDEFINE, а -DMYDEFINE=`cat build-number.txt`, т.е. каждый раз при компиляции make вычислять значение MYDEFINE каким либо образом

ТОгда лучше так: http://stackoverflow.com/questions/8887117/can-cmake-generate-configure-file

отдельный генерируемый config.h

upd (может я что-то туплю, не понял вопрос, сорри)

Интересует как в CMake задать значение переменной, чтобы в результирующем Makefile оно выглядело, например, как:
VERSION_BUILD=$(shell cat build-number.txt)

Это больше похоже на хак. Даже если ты запишешь эту переменную в результирующий Makefile, как ты ее потом будешь использовать? CMake ничего про нее не знает. Проще всего динамически создавать *.h файл кастомной командой на PRE_BUILD этапе. Команда будет вызываться перед каждой сборкой, при условии что исходники изменились и нужна пересборка. У меня это выглядит вот так:

add_custom_command(TARGET ${PROJECT_NAME} PRE_BUILD COMMAND update_version.sh WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/scripts)

add_definitions(-DMYDEFINE)

Лучше target_compile_definitions: https://cmake.org/cmake/help/v3.3/command/target_compile_definitions.html

Во-первых, нужно сразу уяснить, что директорий сборки может быть больше одной, соответственно, на машинах разных пользователей эти номера будут генерировать по разному. Если сохранять номер сборки во временный файл (к примеру, в директорию сборки), то он будет удалён вместе с ней и вся информация о номере версии канет в лету. То-есть файл с номером сборки должен быть или персистентным (сохраняться в систему контроля версий для всех пользователей) или должен использоваться исключительно на одной машине (билд-сервере?).

Касательно реализации. Для безусловного увеличения версии и пересборке программы при каждом запуске в CMake 3.2+ специально добавили ключевое слово BYPRODUCTS:

https://cmake.org/cmake/help/v3.3/command/add_custom_command.html
https://cmake.org/cmake/help/v3.3/command/add_custom_target.html

Могу быстро набросать вариант кода как его использовать для инкремента номера. Остальные варианты предложенные выше работать не будут, поскольку инкрементальная сборка даже не запустится, ибо артефакты сборки уже новее исходников.

Не очень понятно, почему файл должен удалиться, если только нет специальных целей для удаления генерируемых файлов по маске. Насколько понимаю, создаваемый при помощи cmake Makefile четко контролирует только созданные им же файлы.Исходники же не удаляются.

Да, интересно было бы посмотреть на ваш вариант с BYPRODUCTS

Любая директория сборки временная, их может быть много, её полное удаление и переконфигурирование нормальная процедура. Кроме того, CMake сам удалит файл с версией если изменится командная строка для её генерации, в примере выше (от archie) если захочется поменять название update_version.sh на update_build_number.sh, то файл с версией будет удалён.

Скрипты генерации сделал на самом языке CMake для кроссплатформенности, можно переписать на bash или чём-угодно. Номер версии сохраняется в директорию с исходниками. Кусок C++-кода генерируется в директорию сборки.

CMakeLists.txt

cmake_minimum_required(VERSION 3.2)

# generate build_number
add_custom_target(generate_build_number
	COMMAND ${CMAKE_COMMAND}
		-D "BUILD_NUMBER_FILE=${CMAKE_CURRENT_SOURCE_DIR}/build_number"
		-P "${CMAKE_CURRENT_SOURCE_DIR}/generate-build-number.cmake"
	BYPRODUCTS "${CMAKE_CURRENT_SOURCE_DIR}/build_number"
)

# generage cpp from build_number
add_custom_command(
	OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/build_info.cpp"
	COMMAND ${CMAKE_COMMAND}
		-D "BUILD_NUMBER_FILE=${CMAKE_CURRENT_SOURCE_DIR}/build_number"
		-D "CPP_FILE=${CMAKE_CURRENT_BINARY_DIR}/build_info.cpp"
		-P "${CMAKE_CURRENT_SOURCE_DIR}/generate-build-info-cpp.cmake"
	DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/build_number"
)

add_executable(myapp main.cpp "${CMAKE_CURRENT_BINARY_DIR}/build_info.cpp")
add_dependencies(myapp generate_build_number)

generate-build-number.cmake

if ( NOT EXISTS "${BUILD_NUMBER_FILE}" )
	set(build_number 1)
else()
	file(READ "${BUILD_NUMBER_FILE}" build_number)
	string(STRIP "${build_number}" build_number)
	math(EXPR build_number "${build_number} + 1")
endif()

file(WRITE "${BUILD_NUMBER_FILE}" "${build_number}\n")

generate-build-info-cpp.cmake

file(READ "${BUILD_NUMBER_FILE}" build_number)
string(STRIP "${build_number}" build_number)

string(TIMESTAMP timestamp)

file(WRITE "${CPP_FILE}"
	"extern const int build_number = ${build_number};\n"
	"extern const char * const build_time = \"${timestamp}\";\n"
)

main.cpp

#include <iostream>

extern const int build_number;
extern const char * const build_time;

int main(int argc, char ** argv)
{
	std::cout << "number: " << build_number << ", time: " << build_time << "\n";
	return 0;
}

Спасибо. Приведенный пример не совсем работает:

$ make
Scanning dependencies of target generate_build_number
[  0%] Built target generate_build_number
[ 33%] Generating build_info.cpp
CMake Error: Error processing file: /home/user/Test/cmake/autobuild/generate-build-info-cpp.cmake
CMakeFiles/myapp.dir/build.make:53: recipe for target 'build_info.cpp' failed
make[2]: *** [build_info.cpp] Error 1
CMakeFiles/Makefile2:91: recipe for target 'CMakeFiles/myapp.dir/all' failed
make[1]: *** [CMakeFiles/myapp.dir/all] Error 2
Makefile:75: recipe for target 'all' failed
make: *** [all] Error 2

хотя номер билда в файле инкрементируется.

generate-build-info-cpp.cmake

Точно файл с таким именем, без опечаток?

$ ls -1
build_info.cpp
build_number
CMakeCache.txt
CMakeFiles
cmake_install.cmake
CMakeLists.txt
generate-build-info-cpp.cmake
generate-build-number.cmake
main.cpp
Makefile

вроде бы да

build_info.cpp

Я вижу файл был сгенерирован, то-есть скрипт выполнился, откуда же ошибка?

Спасибо. Вроде бы заработало. Что было - не разобрался, видимо, какие-то издержки копипаста...