Выборка строк из диапозона

Нужно достать «Xxxxx»?

echo '!!!екфтызю Ф133Ж ЯФВУКОЛФ зщ зкшсршту Xxxxxx xxxxx. вцфвфцвцфвцфвфцвфцвцфв вцфвфцвцфивцфрвцфвоцфтвоцфтвоцфтвофцтовфцтов вошцошвфошовшцофшвошцфошвоцшф 10 вофцшвошфцовшфцошв 09:12:11' | awk '{print $6}'

надеюсь я доступно обьяснил.

Пример просто жесть, да и объяснение не лучше.

Сейчас попробую объяснить лучше Пример ошибки

!!!Транспорт xg813 задержка по причине Ожидание связи

вцфвфцвфцвфцвфцвфцв

вцфвфцвфцвфцвфцвфц

вфцвфцвфцвфцвфцв

Время начала задержки : 08:12:03

---Принято

И таких сообщений в файле много. Хочу для каждого такого сообщения вычленить xg813 08:12:03 Принято. Сообщений много разных, уникальный идентификатор ошибки это Ожидание связи

Ну сначала вы другую строку показывали. И вообще это одна строка?

Если у вас каждое сообщение пишется полностью одной строкой, «место» нужных полей в строке не меняется, то awk - самый простой вариант. Если строк несколько то придется городить костыли.

Формат сообщения в последним посту ровно такой какой есть. Я смотрел в сторону sed, но что-то не получается. Про какие костыли вы говорите?

Если у вас там несколько строк то придется грепать, при этом используя регулярки, это и есть костыли.

простая стейт-машина на perl (или awk)

А если грепнуть все такие исключения из файла и записать одной монолитной строкой без пробелов и энтеров, а потом использовать awk. Так покатит?

Не понял. Если у вас есть строка, в которой положение нужных элементов не меняется, то вы просто говорите «awk, дай мне столбцы 2, 4 и 16». Если у вас там на каждой строке что-то уникальное (ну относительно, в рамках одного сообщения хотя бы), то вам нужно строить конструкцию типа «если строка начинается со слова, которое соответсвует регулярке str[0-9][a-z] то дай мне второй столбец этой строки, если строка начинается с дефиса дай мне символы с третьего по пятнадцатый, а из всех остальных строк выбери подстроки короче 6 символов», что пишется и дебажится гораздо сложнее первого варианта.

Так?

$ cat log.txt
sdfsdfsd
!!!Транспорт xg813 задержка по причине Ожидание связи
вцфвфцвфцвфцвфцвфцв
вцфвфцвфцвфцвфцвфц
вфцвфцвфцвфцвфцв
Время начала задержки : 08:12:03
---Принято
sdfsdf
!!!Транспорт xg813 ускорение по причине Слишком быстрая связь
вцфвфцвфцвфцвфцвфцв
вцфвфцвфцвфцвфцвфц
вфцвфцвфцвфцвфцв
Время начала задержки : 08:12:03
---Принято
dfsafa
!!!Транспорт xg813 задержка по причине Ожидание связи
вцфвфцвфцвфцвфцвфцв
вцфвфцвфцвфцвфцвфц
вфцвфцвфцвфцвфцв
Время начала задержки : 08:12:03
---Принято
dfsafa

$ cat log.txt | sed -n '/задержка/,/^---/ p' | grep 'задержка\|Время начала задержки\|^---' | sed 's/^!!!Транспорт \([^ ]\+\).*$/\1/g' | sed 's/^Время начала задержки : //g' | sed 's/^---//g' | sed 'N;N;s/\n/ /g'
xg813 08:12:03 Принято
xg813 08:12:03 Принято

уникальный идентификатор ошибки это Ожидание связи

Не сразу прочитал. В моем примере идентификатором было «задержка».

Можно и на sed, сработает с вероятностью 50%: или сработает или нет.

#!/usr/bin/sed -rnf

# search for '!!!' at the beginning of a line
s/^!!!//; 

# skip everything below and start new cycle if not found
T; 

# found; extract 'xx000'
s/.* (..[0-9]{3}) .*/\1 /; 

# and 'hold' it
H; 

# do {read new line; try to extract pattern;} 
#     while not found '..:..:..'
:l1; 
    n; 
    s/.*(..:..:..).*/\1 /; 
    T l1;
    
# append what's been found to previous 'hold'
H;

# do {read new line; try to extract pattern;} 
#     while not found '---' at the beginning of a line
:l2; 
    n; 
    s/^---(.*)/\1/; 
    T l2;

# append everything after '---' to our 'hold'
H;

# bring 'hold space' in the context
x;

# remove all newline chars it has
s/\n//g;

# print result
p;

# clear 'hold'
s/.*//;x;

# repeat whole cycle for next line

Запускать так:

$ chmod +x script.sed
$ ./script.sed messages.txt

Тот же скрипт, но через командную строку:

$ sed -rn 's/^!!!//;T;s/.* (..[0-9]{3}) .*/\1 /;H;:l1;n;s/.*(..:..:..).*/\1 /;T l1;H;
           :l2;n;s/^---(.*)/\1/;T l2;H;x;s/\n//g;p;s/.*//;x;' \
           messages.txt

Типо

awk '/^!!!/{a=$2}/^Время/{b=$5}/^---/{print a,b,$0}' file.txt

А простая state-машина на BASH не существует что ли?

Ограничение BASH - только скорость обработки файла строка за строкой. Если торопится некуда - никаких sed, awk и тем более зperl'а здесь не нужно.

Огромное спасибо !

Очень помог ваш комент, немножко под свои нужды переписал и все четко!

Welcome
Помечай тему как решенную.