perl, дублирование STDERR в переменную

На ум приходит tied handle, смотри perldoc perltie (секцию Tying FileHandles) и perldoc Tie::Handle. Вроде нет причин, чтобы оно не
работало ;-)
Ну и на CPAN посмотри, там много чего tied было.

HTH

Большое спасибо, судя по всему это как раз то, что мне надо.

> А вот как сделать, чтобы одновременно выводилось и туда и туда?

Могу подсказать решение, оно прямо-таки гениально. Создай процедуру, назови её как-нибудь, log_msg() например, и код её будет состоять из двух строк - одна пишет в STDERR, другая туда, куда тебе там ещё нужно. Гениально, потому что просто.

Это конечно так, но стандартные ошибки типа using uninitialized variable про это знать не будут =) Я уже сделал, если интересно, могу показать.

Покажи.

HandleDuplicator.pm:
# class to duplicate file handle
# Usage: tie *HNDL, 'HandleDuplicator', *ANOTHER_HANLE, \$var
# Each time when the writing to the HNDL requsted,
# data will be written to the ANOTHER_HANDLE and
# added to the $var
package HandleDuplicator;
use warnings;
use strict;
use base 'Tie::Handle';

# Parameters:
#  1. File handle
#  2. Scalar ref
sub TIEHANDLE
{
    my $class = shift;
    my $self;
    $self->{handle} = shift;
    $self->{variable} = shift;
    bless $self, $class;
}

sub WRITE
{
    my $self = shift;
    my $data = shift;

    ${$self->{variable}} .= $data;
    my $hndl = $self->{handle};
    print $hndl $data;
}

1;

StdErrLog.pm:
# all messages passed through the stderr will be logged.
# just use StdErrLog; and call StdErrLog::log to get the data.
# StdErrLog::clear clears the internal buffer.
package StdErrLog;
use warnings;
use strict;
use HandleDuplicator;

my $log = '';

sub log()
{
    return $log;
}

sub clear()
{
    $log = '';
}

sub BEGIN
{
    open(my $stderr, ">&2") || die "Can't duplicate stderr: $!";
    tie *STDERR, 'HandleDuplicator', $stderr, \$log;
}

1;

Английский ужасен, я знаю :)

2Legioner:

Гы ;-) Я думал, больше кода потребуется. Выглядит вроде симпатично :-)