Пропадает сеть

#!/usr/bin/perl
#

use strict;
use warnings;

use POSIX;

my $timeout = 5;

my @interfaces = (
                {
                        name    => 'eth0',
                        active  =>      1,
                        irq             =>      23,
                        address =>      '10.0.0.10',
                        net             =>      '10.0.0.0',
                        netmask =>      '24',
                        gateway =>      '10.0.0.11',
                        table   =>      'test'
                },
                {
                        name    => 'eth1',
                        active  =>      1,
                        irq             =>      23,
                        address =>      '192.168.1.1',
                        net             =>      '192.168.1.0',
                        netmask =>      '24',
                        gateway =>      '',
                        table   =>      'main'
                },
                {
                        name    => 'eth2',
                        active  =>      1,
                        irq             =>      23,
                        address =>      '172.16.0.25',
                        net             =>      '172.16.0.0',
                        netmask =>      '24',
                        gateway =>      '172.16.0.254',
                        table   =>      'main'
                }
);

my $atable = 'test';

my $logfile = "/var/log/asm_fix.log";
open(my $log, '>>', $logfile);
select($log);
$| = 1;

sub timestamp {
        my $time = localtime();
        return("$time ");
}

sub irq_state {
        my $irq = shift;
        open(my $spurious, '<', "/proc/irq/$irq/spurious");
        my $line;
        while (<$spurious>) {
                $line = $_;
                last if $. == 1;
        }
        my @string = split(' ', $line);
        close($spurious);
        return $string[1];
}

sub iface_restart {
        my $iface = shift;
        print(timestamp(), "Restarting interface $$iface{'name'} $$iface{'address'}\n");
        my @command;
        @command = ('ip', 'link', 'set', 'down', 'dev', $$iface{'name'});
        print(timestamp(), join(' ', @command, "\n"));
        system(@command);
        @command = ('ip', 'link', 'set', 'up', 'dev', $$iface{'name'});
        print(timestamp(), join(' ', @command, "\n"));
        system(@command);
        @command = ('ip', 'route', 'add', "$$iface{'net'}/$$iface{'netmask'}", 'dev', $$iface{'name'}, 'proto', 'kernel', 'scope', 'link', 'src', $$iface{'address'}, 'table', $atable);
        print(timestamp(), join(' ', @command, "\n"));
        system(@command);
        if ($$iface{'gateway'}) {
                @command = ('ip', 'route', 'add', 'default', 'via', $$iface{'gateway'}, 'table', $$iface{'table'});
                print(timestamp(), join(' ', @command, "\n"));
                system(@command);
        }
        print(timestamp(), "Interface $$iface{'name'} restarted\n");
}

print(timestamp(), "Starting.\n");
my $pid = fork();
exit if $pid;
die "Couldn't fork: $!\n" unless defined($pid);

POSIX::setsid() or die "Can't start a new session: $!\n";

my $time_to_die;

sub signal_handler {
        print(timestamp(), "Exiting.\n");
        close($log);
        $time_to_die = 1;
}
$SIG{INT} = $SIG{TERM} = $SIG{HUP} = \&signal_handler;
$SIG{PIPE} = 'IGNORE';

until ($time_to_die) {
        sleep($timeout);
        foreach my $interface (@interfaces) {
                if ($$interface{'active'}) {
                        my $count = irq_state($$interface{'irq'});
                        if ($count == 0) {
                                iface_restart($interface);
                        }
                }
        }
}