sed: изменить только внутри ЧАСТИ строки, которая соответствует паттерну

4 - это 4-ое совпадение?
Не подходит, ибо цифр и точек может быть произвольное количество.

a sed принципиален?

awk '{gsub(/\./,"|",$2);print}'

А как сделать чтобы менялось только в той части, что после табуляции?

Можно так, но надо ли ону кому такое страшное?

$ echo -e "abc_1.2.3.4_cde\t1.2.3.4" |
sed '/\t[0-9.]\+/ { h; x; s/\t[0-9.]\+/\n/; x; s/.*\(\t[0-9.]\+\).*/\1/; y/./|/; H; x; s/\([^\n]*\)\n\([^\n]*\)\n\(.*\)/\1\3\2/ }'
abc_1.2.3.4_cde 1|2|3|4

• исходная строка кладётся в hold как <до>\n<после>
• в pattern оставляем только <середину>
• выполняем замену
• дописываем результат в hold и получаем <до>\n<после>\n<середина после замены>
• меняем последние две части местами, удаляя переводы строк

Сделал из интереса, сам бы не стал использовать.

Два варинта, первый в цикле заменяем точки после табуляции:

echo -e "abc_1.2.3.4_cde\t1.2.3.4" | sed ':a;s/\(\t[^.]*\)./\1|/g; ta'

echo -e "abc_1.2.3.4_cde\t1.2.3.4" | sed 'h;s/\t.*//;x;s/[^\t]*//;s/\./|/g;H;x;s/\n//'

несколько sed

echo -e "abc_1.2.3.4_cde\t1.2.3.4" | sed 's/\t[0-9\.]/\n/' | sed 'n;s/\./|/g' | sed 'N;s/\n/\t/'

a sed принципиален?

Принципе нет, но тогда мне нужно будет учить awk; например, как делать подстановки вида sed'овского \1 с нахрапа не нашел.

Хотя, должен признаться, что вариант с awk более гибкий и наглядный.

Спасибо. Сделал первым способом.
Реальная задача состояла в замене однозначных чисел двузначными. Вот что вышло:

$ echo -e "abc_1.2.3.4_cde\t1.2.3.4" | sed ':a;s/\t\(\([0-9]\{2,\}\.\)*\)\([0-9]\)\(\.\|\t\|$\)/\t\10\3\4/g;ta'
abc_1.2.3.4_cde 01.02.03.04